home *** CD-ROM | disk | FTP | other *** search
/ PD Collection CD 1 / PD Collection CD 1.iso / textual / tex / files / !tex / mfinputs / romlig / mf
Encoding:
Text File  |  1988-02-26  |  7.7 KB  |  165 lines
  1. % This is ROMLIG.MF in text format, as of Mar 31, 1986.
  2. % This file describes five roman ligatures that begin with `f'
  3. % and puts them in code positions \0013--\0017.
  4.  
  5. numeric itc#; % modified italic correction on `f' and `ff'
  6. itc#=if serifs: max(0,flare#-.25u#) else: 1.25u# fi;
  7.  
  8. ligtable "f": "i"=:oct"014", "f"=:oct"013", "l"=:oct"015",
  9.  "'" kern itc#, "?" kern itc#, "!" kern itc#, ")" kern itc#, "]" kern itc#;
  10. ligtable oct"013": "i"=:oct"016", "l"=:oct"017",
  11.  "'" kern itc#, "?" kern itc#, "!" kern itc#, ")" kern itc#, "]" kern itc#;
  12.  
  13. cmchar "The ligature ff";
  14. beginchar(oct"013",10.5u#+2letter_fit#,asc_height#,0);
  15. italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
  16. adjust_fit(0,0);
  17. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  18. pos11(stem',0); rt x11r=hround(w-3u+.5stem');
  19. pickup fine.nib; numeric bulb_diam, inner_jut;
  20. if serifs: bulb_diam=hround .8[stem,flare];
  21.  pos2(bulb_diam,0); pos12(bulb_diam,0);
  22.  rt x2r=hround(rt x11r-stem_corr); lft x12l=hround(w-.75u+.5);
  23.  y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
  24.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  25.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  26. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 6.25u;
  27.  pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(w+.75u); fi
  28. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  29. f_stroke(11,12,d,e,f,inner_jut,1.25jut); % right stem, arc, terminal, serif
  30. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  31. pos3(bar,90); pos4(bar,90);
  32. rt x4=hround(w-1/3u);
  33. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  34.  pos4'(bar,90); x4'=x11; y4'=y4;
  35.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  36. else: filldraw stroke z3e--z4e; fi  % bar
  37. penlabels(1,2,3,4,11,12); endchar;
  38.  
  39. cmchar "The ligature fi";
  40. beginchar(oct"014",10u#+2letter_fit#,asc_height#,0);
  41. italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
  42. adjust_fit(0,serif_fit#);
  43. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  44. pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
  45. pos12(stem',0); x11=x12; bot y12=0;
  46. pickup fine.nib; numeric bulb_diam, inner_jut;
  47. if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
  48.  pos2(bulb_diam,0); x2r=x12r;
  49.  y2+.5bulb_diam=.8[x_height,h+oo]; top y11=x_height+min(oo,serif_drop);
  50.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  51.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  52. else: bulb_diam=max(stem,dot_size);
  53.  pos2(6/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u;
  54.  pickup tiny.nib; pos13(bulb_diam,0); pos14(bulb_diam,90);
  55.  x13=x11-.5; top y14r=min(2x_height,h+1); top y11=x_height;
  56.  if bot y14l-x_height<tiny: y14l:=min(y14r-eps,y11+2tiny); fi
  57.  x13=x14; y13=.5[y14l,y14r]; dot(13,14);  % dot
  58. fi;  % this is the ligature we're drawing
  59. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  60. pickup tiny.nib; filldraw stroke z11e--z12e;  % right stem
  61. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  62. pos3(bar,90); pos4(bar,90);
  63. if serifs: x4=x11;  % bar will overlap upper right serif
  64.  sloped_serif.l(11,12,d,1/3,jut,min(oo,serif_drop));  % upper right serif
  65.  dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut);  % lower right serif
  66. else: rt x4= hround 5.3u; fi
  67. pickup crisp.nib; filldraw stroke z3e--z4e;  % bar
  68. penlabels(1,2,3,4,11,12,13,14); endchar;
  69.  
  70. cmchar "The ligature fl";
  71. beginchar(oct"015",10u#+2letter_fit#,asc_height#,0);
  72. italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
  73. adjust_fit(0,serif_fit#);
  74. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  75. pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
  76. pos12(stem',0); x11=x12; bot y12=0; top y11=h;
  77. filldraw stroke z11e--z12e;  % right stem
  78. pickup fine.nib; numeric bulb_diam, inner_jut;
  79. if serifs: bulb_diam=hround .8[stem,flare];
  80.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  81.  y2+.5bulb_diam=.9[x_height,h+oo];
  82.  sloped_serif.l(11,12,d,1/3,eps,max(serif_drop,oo)); % erase excess at top
  83.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  84.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  85. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u; fi
  86. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  87. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  88. pos3(bar,90); pos4(bar,90);
  89. if serifs: x4=x11;
  90.  dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut);  % lower right serif
  91. else: rt x4= hround 5.3u; fi
  92. pickup crisp.nib; filldraw stroke z3e--z4e;  % bar
  93. penlabels(1,2,3,4,11,12); endchar;
  94.  
  95. cmchar "The ligature ffi";
  96. beginchar(oct"016",15u#+4letter_fit#,asc_height#,0);
  97. italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
  98. adjust_fit(0,serif_fit#);
  99. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  100. pos11(stem',0); lft x11l=hround(.5w-.5stem');
  101. pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
  102. pos22(stem',0); x21=x22; bot y22=0;
  103. pickup fine.nib; numeric bulb_diam, inner_jut;
  104. if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
  105.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  106.  pos12(bulb_diam,0); x12r=x21r;
  107.  top y21=x_height+min(oo,serif_drop);
  108.  y2+.5bulb_diam=.8[x_height,h+oo]; y12=y2;
  109.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  110.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  111. else: bulb_diam=max(stem,dot_size);
  112.  pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
  113.  pos12(6/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u);
  114.  pickup tiny.nib; pos23(bulb_diam,0); pos24(bulb_diam,90);
  115.  x23=x21-.5; top y24r=min(2x_height,h+1); top y21=x_height;
  116.  if bot y24l-x_height<tiny: y24l:=min(y24r-eps,y21+2tiny); fi
  117.  x23=x24; y23=.5[y24l,y24r]; dot(23,24); fi  % dot
  118. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  119. f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
  120. pickup tiny.nib; filldraw stroke z21e--z22e;  % right stem
  121. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
  122. pos3(bar,90); pos4(bar,90);
  123. if serifs: x4=x21;  % bar will overlap upper right serif
  124.  sloped_serif.l(21,22,g,1/3,jut,min(oo,serif_drop));  % upper right serif
  125.  dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut);  % lower right serif
  126. else: rt x4=hround(.5w+2.8u); fi
  127. pickup crisp.nib;
  128. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  129.  pos4'(bar,90); x4'=x11; y4'=y4;
  130.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  131. else: filldraw stroke z3e--z4e; fi  % bar
  132. penlabels(1,2,3,4,11,12,21,22,23,24); endchar;
  133.  
  134. cmchar "The ligature ffl";
  135. beginchar(oct"017",15u#+4letter_fit#,asc_height#,0);
  136. italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
  137. adjust_fit(0,serif_fit#);
  138. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  139. pos11(stem',0); lft x11l=hround(.5w-.5stem');
  140. pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
  141. pos22(stem',0); x21=x22; bot y22=0; top y21=h;
  142. filldraw stroke z21e--z22e;  % right stem
  143. pickup fine.nib; numeric bulb_diam, inner_jut;
  144. if serifs: bulb_diam=hround .8[stem,flare];
  145.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  146.  pos12(bulb_diam,0); x12r=x21r-stem_corr;
  147.  y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
  148.  sloped_serif.l(21,22,g,1/3,eps,max(serif_drop,oo)); % erase excess at top
  149.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  150.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  151. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
  152.  pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u); fi
  153. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  154. f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
  155. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
  156. pos3(bar,90); pos4(bar,90);
  157. if serifs: dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut);  % lower right serif
  158.  pickup crisp.nib; x4=x21;
  159. else: rt x4=hround(.5w+2.8u); fi
  160. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  161.  pos4'(bar,90); x4'=x11; y4'=y4;
  162.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  163. else: filldraw stroke z3e--z4e; fi  % bar
  164. penlabels(1,2,3,4,11,12,21,22); endchar;
  165.